@cards のデータが . 演算子で文字列連結でき、「,」を含まないデータならそれも良いですが、量が増えるとソート時の split に負荷がかかり、s// で連結文字列の除外というのもトリッキーな気がします。

そのアルゴリズムのまま、もう少し工夫するとこんな感じでしょうか。

#! /usr/bin/perl
use strict;

### @cardsは1から10までの数値の配列
my @cards = (1..10);

### 元の値と、並べ替え用のキー（乱数）を持ったハッシュに置き換えます
$_ = {key => rand(), value => $_} for(@cards);

### 並べ替え用のキーでソートします
@cards = sort {$a->{'key'} <=> $b->{'key'}} @cards;

### 元の値に戻します
$_ = $_->{'value'} for(@cards);

## 結果の表示
print "$_\n" for (@cards);



参考までに、よくある汎用な配列のシャッフルはこんな感じじゃないでしょうか？

#! /usr/bin/perl
use strict;

sub shuffle(@) {
    my @list = @_;
    my @ret = ();

    push(@ret, splice(@list, int(rand(scalar(@list))), 1)) while(@list);

    return @ret;
}


my @cards = (
    { name => 'AAA', value => '1' },
    { name => 'BBB', value => '2' },
    { name => 'CCC', value => '3' },
    { name => 'DDD', value => '4' },
    { name => 'EEE', value => '5' },
    { name => 'FFF', value => '6' },
    { name => 'GGG', value => '7' },
    { name => 'HHH', value => '8' },
    { name => 'III', value => '9' },
    { name => 'JJJ', value => '0' },
);

foreach my $item (shuffle @cards) {
    printf "[%s] - [%d]\n", $item->{'name'}, $item->{'value'};
}